Reference

$ rfn explain debt.principal
debt.principal  "Principal"
  where   Debt!H33 (first period; the same formula runs across the row)
  unit    USD
  formula =IF(H$23,MIN(MAX(H$32/$D$12-H$31,0),H$26),0)
  note    Sculpted: repay what the target DSCR allows, never more than is owed
  reads   debt.tenor, debt.cfads, inputs.target_dscr, debt.interest, debt.loan.opening
  read by debt.dscr, debt.import.debt.principal …

file        := declaration*
declaration := model | timeline | inputs | table | module | statement | check | dashboard | sensitivities | scenarios

model       := "model" STRING "{" (SETTING VALUE)* "}"          currency, display, decimals, day_count, data, sheets,
                                                                 tax, discount, reports, conventions, drawdown,
                                                                 vat, vat_refund, vat_facility, navigator, valid_until
tax         := "tax" (formula | "{" (TAXRULE formula)* "}")
TAXRULE     := rate | holiday | holiday_rate | loss_expiry | loss_limit | interest_cap | minimum | withholding
drawdown    := "drawdown" (ORDER | "{" ("before" "financial_close" ":" NAME)?
                ("from" "financial_close" ":" ORDER)? ("equity" "in_order" LIST)? "}")
ORDER       := pro_rata ("on" (uses | costs))? | equity_first | debt_first | back_ended | "in_order" LIST
LIST        := "[" (NAME | "[" NAME ("," NAME)* "]") ("," …)* "]"        [ ]: pari passu
timeline    := "timeline" "{" "start" DATE ("step" STEP)? ("fiscal_year" "ends" MONTH)? phase* ("spare" LENGTH)? "}"
phase       := NAME (LENGTH | NAME "(" (case ":" LENGTH),+ ")") ("step" STEP)?
                                                                 STEP: month | quarter | half | year
inputs      := "inputs" STRING "{" input* "}"
input       := DOC* NAME "=" value STRING? annotation* ("|" "grow" formula "from" formula)?
annotation  := "@source" STRING | "@note" STRING
table       := DOC* "table" NAME ":" unit ("sheet" STRING)? ("by" NAME | "by" "[" NAME ("," NAME)* "]")?
scenarios   := DOC* "scenarios" NAME STRING? ("start" NAME)? "{" (NAME STRING?)+ "}"   an input's value may then be NAME "(" case ":" value, … ")"

module      := "module" NAME STRING? "{" item* "}"
item        := line | "solve" line | KIND line | "shares" NAME "up" "to" formula STRING? | balance | funding
line        := DOC* NAME (":" unit)? "=" formula ("|" "during" formula)* TAIL* STRING? ("tolerance" formula)?
KIND        := revenue | cost_of_sales | cost | income | capex | reserve | use | shares
                                                                 read only before a line's name
TAIL        := ("life" | "allowance") formula | "vat" (recoverable | capitalised | none)    capex only
balance     := "balance" NAME ":" unit "{" ("start" formula)? (("+" | "-") formula STRING?)* "}"
funding     := "funding" NAME "{" "first" (source | "pro_rata" "{" shared* "}") ("then" source)* "}"
source      := NAME ("up" "to" formula | "rest")
shared      := NAME ("share" formula ("up" "to" formula)? | "rest")

statement   := "statement" NAME STRING? ("|" ("sum" "by" GRAIN | "at" GRAIN ("end" | "start")))?
               "{" (("+" | "-" | "=") formula STRING? | "+" MODULE | "section" STRING)* "}"
                                                                 GRAIN: year | half
check       := ("check" | "alert") STRING formula ("at" NAME)? ("tolerance" formula)? ("|" "during" formula)*
dashboard   := "dashboard" "{" ("section" STRING | NAME STRING? | chart)* "}"
chart       := "chart" ("column" | "line") STRING "{" (NAME STRING?)* "}"
sensitivities := "sensitivities" "{" "results" "{" (NAME STRING?)* "}" ("case" STRING "{" change* "}")* "}"
change      := NAME ("*" | "+" | "-") value | NAME "=" NAME      the second picks a scenario's case

formula     := value | NAME | NAME "(" arguments? ")" | "(" formula ")" | "-" formula
             | formula OPERATOR formula | "if" formula "then" formula "else" formula
             | formula "of" NAME                                 in a loan's size: or a class of shares' up to
             | "{" NAME ":" formula ("," NAME ":" formula)* "}"   a record: a capex's depreciation:
             | "[" formula ("," formula)* "]"                   a list: depreciation's schedule:
OPERATOR    := + - * / ^ == != < <= > >= "and" "or"
arguments   := (NAME ":")? formula ("," (NAME ":")? formula)*
value       := NUMBER unit? | DATE
unit        := WORD ("/" WORD)* | "%" | "%/y"